2. Fórumok
  3. OS, alkalmazások
  4. Microsoft Excel topic
  5. (kiemelt téma)
  • Téma összefoglaló
    Utoljára frissítve: 2023-11-13 08:31

    IT café

    A Microsoft Excel topic célja segítséget kérni és nyújtani Excellel kapcsolatos problémákra.
    Kérdés felvetése előtt olvasd el, ha még nem tetted.

Új hozzászólás Aktív témák

  • #15791 Mutt aktív tag Vladek83 #15769
    Új Válasz #15791
    Új hozzászólás
    Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra
    Privát üzenet küldése

    Mutt

    aktív tag

    válasz Vladek83 #15769 üzenetére

    Az A1 cella tartalmaz érvényesítési listát (pl.: alma, körte), most ha elfogy valamelyik, akkor üres cellát kell, hogy adjon, viszont szeretném továbbra is a listából kiválasztani az adott gyümölcsöt

    Remélem jól értettem, hogy mire van szükséged. Itt megnézheted, hogy mire jutottam.

    A megoldás nem egyszerű, de itt vannak a lépések. Én Validation-ként neveztem el a lapot, amelyen ezeket kell csinálnod:
    1. Az eredeti lista (pl. alma, körte stb. ABC sorrendben). Az elemek A2-es cellától indulva vannak felsorolva.
    2. Az A1-es cella legyen üres.
    3. Jelöld ki az A1:Axx cellákat (xx az utolsó sor ahol van még elemed) és ezt a tartományt nevezd el, én "original"-nak hívtam.
    4. B1 cellába másold be ezt a képletet: =DARAB2(A:A)
    vagyis megszámoljuk, hogy hány elemet vittél be az A-oszlopba, ezt még használni fogjuk később.
    5. B2-be írd be ezt:
    =HA(C2="";"";DARABTELI(ELTOLÁS($C$2;0;0;$B$1);"<="&C2))
    ez a függvény majd abban segít hogy az érvényesítésnél ABC sorrendbe tesszük a megmaradt elemeket
    6. B2-beli függvényt húzd le (másold) legalább annyi sorig ahány elemed van.
    7. C2-be menjen ez: =HA(HIBÁS(HOL.VAN(A2;[B]Data!A:A[/B];0));A2;"")
    ez megkeresi hogy a Data fülön (a képletben ezt javítsd a saját névre) ahol kiválasztod a termékeket, már megtalálható-e valamelyik eleme
    8. C2-beli függvényt húzd le (másold) legalább annyi sorig ahány elemed van.
    9. D2-be kell ez:
    =HAHIBA(FKERES(KICSI(ELTOLÁS($B$2;0;0;$B$1);SOR()-1);ELTOLÁS($B$2;0;0;$B$1;2);2;0);"")
    ez a képlet ABC sorba rendezi azokat az elemeket, amelyeket még nem használtál a Data fülön
    10. D2-beli függvényt húzd le (másold) legalább annyi sorig ahány elemed van.
    11. E1-be tedd ezt: =DARABTELI(D:D;">""")
    egyszerűen megnézzük hogy hány elemet kell majd az érvényesítésnél használni

    Már csak 1 képlet maradt! Amit a Képletek -> Névkezelőben kell megadnod. A neve legyen mondjuk "valasztas".

    12. A hivatkozásba pedig menjen ez:
    =HA(Validation!$E$1=0;original;ELTOLÁS(Validation!$D$2;0;0;Validation!$E$1))
    Ez kiválasztja a maradék elemeket, vagy ha már mindent elhasználtál akkor az eredeti listát.

    Kész is vagy, már csak a Data fülön kell az érvényesítést használnod. Válaszd a lista opciót és forrásnak ezt írd be: =valasztas

    Vége.

    Ps.
    Ahogy látod többször használom a dinamikus tartományokat (ELTOLÁS függvény kombinálva a DARAB függ-nel), amelyek főleg érvényesítésnél tudnak jók lenni.
    Ezen az oldalon nagyon profin leírják, hogy még miként lehet érvényesítésnél dinamikus tartományokat használni.

    [ Szerkesztve ]

    A tanácsaimat ingyen adom. Ha nem tetszik, akkor kérlek ne kritizáld! / https://github.com/viszi/codes/tree/master/Excel

Új hozzászólás Aktív témák